Skip to end of metadata
Go to start of metadata

Author: Ashim Chowdhury
Submitted: November 1, 2006
Related Links:

This article explains how to create your own application logging program in ABAP.
SAP provides standard functionality to write into as well as view the application log. This article will explain in detail how to create your own logging function module for application logging using standard SAP log facility. Two transaction code related to application logging are

  • SLG0 -> Used to maintain the log object
  • SLG1 -> Used to view the log

Configuration step

In this step create a log object.

  1. Open transaction SLG0. An information message about cross-client table will come.
  2. 2. Click the button "New Entries". Enter the name and description of your log object (say ZTESTLOG as object name and "Test Log" as object description) and save.

Development Step

The following standard function modules provided by SAP has been used to create the Z function module for logging.

  • BAL_GLB_MSG_DEFAULTS_SET
  • BAL_DB_SAVE
  • BAL_LOG_MSG_ADD

Here are the steps:

1. Go to transaction SE11. Create a z-structure Z_LOG_MESSAGE having the following fields

Component

Component Type

MSGTY

SYMSGTY

MSG_TEXT_1

SYMSGV

MSG_TEXT_2

SYMSGV

MSG_TEXT_3

SYMSGV

MSG_TEXT_4

SYMSGV

2. Crate a message class say ZMESSAGE in transaction SE91 and a message 999 with four placeholder ( & ) as the text.

3. Go to transaction SE37. Create a function group say ZLOG

4. After the function group is created, create a function module in that group. Let is name it ZIU_MESSAGE_LOGGING.

Import parameters:
a. I_LOG_OBJECT type BALOBJ_D -> Application log: Object name (Application code)
b. I_EXTNUMBER type String -> Application Log: External ID

Export parameters: None
Changing parameters: None
Tables parameters:
T_LOG_MESSAGE type Z_LOG_MESSAGE
Exceptions:
LOG_HEADER_INCONSISTENT
LOGGING_ERROR

Paste the code below as the source code

Error rendering macro 'code': Invalid value specified for parameter 'com.atlassian.confluence.ext.code.render.InvalidValueException'
FUNCTION ZIU_MESSAGE_LOGGING.
*"----------------------------------------------------------------------
*"*"Local interface:
*" IMPORTING
*" REFERENCE(I_LOG_OBJECT) TYPE BALOBJ_D
*" REFERENCE(I_EXTNUMBER) TYPE STRING
*" TABLES
*" T_LOG_MESSAGE STRUCTURE Z_LOG_MESSAGE
*" EXCEPTIONS
*" LOG_HEADER_INCONSISTENT
*" LOGGING_ERROR
*"----------------------------------------------------------------------

* Author :Ashim Chowdhury

* DESCRIPTION: This function module is used insert messages in the
* application log

  CONSTANTS: c_message TYPE syst-msgid VALUE 'ZMESSAGE',
  c_999 TYPE syst-msgno VALUE '999'.

  DATA:
  l_log_handle TYPE balloghndl,
  l_s_log TYPE bal_s_log,
  l_dummy TYPE string,
  l_ext_no TYPE bal_s_log-extnumber,
  l_s_mdef TYPE bal_s_mdef.

  IF t_log_message[] IS NOT INITIAL.

    l_s_log-object = i_log_object.
    l_ext_no = i_extnumber.
    l_s_log-extnumber = l_ext_no.

* Create the log with header data
    CALL FUNCTION 'BAL_LOG_CREATE'
      EXPORTING
        i_s_log                 = l_s_log
      IMPORTING
        e_log_handle            = l_log_handle
      EXCEPTIONS
        log_header_inconsistent = 1
        OTHERS                  = 2.

    IF sy-subrc <> 0.
      CASE sy-subrc.
        WHEN 1.
          RAISE log_header_inconsistent.
        WHEN OTHERS.
          RAISE logging_error.
      ENDCASE.
    ENDIF.

    l_s_mdef-log_handle = l_log_handle.

* Set the default value
    CALL FUNCTION 'BAL_GLB_MSG_DEFAULTS_SET'
      EXPORTING
        i_s_msg_defaults = l_s_mdef
      EXCEPTIONS
        OTHERS           = 0.

* Loop the message table and write the messages into the log
    LOOP AT t_log_message.

* Use the message type ZMESSAGE and msg no 999
* Issue the message in a dummy variable
      MESSAGE ID c_message TYPE t_log_message-msgty NUMBER c_999
      WITH t_log_message-msg_text_1 t_log_message-msg_text_2
      t_log_message-msg_text_3 t_log_message-msg_text_4
      INTO l_dummy.

* The parameters set by message statement will be used
* Add the message in the log
      PERFORM msg_add.
    ENDLOOP.


* save logs in the database
    CALL FUNCTION 'BAL_DB_SAVE'
      EXPORTING
        i_save_all       = 'X'
      EXCEPTIONS
        log_not_found    = 1
        save_not_allowed = 2
        numbering_error  = 3
        OTHERS           = 4.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.

  ENDIF.

ENDFUNCTION.
Error rendering macro 'code': Invalid value specified for parameter 'com.atlassian.confluence.ext.code.render.InvalidValueException'
*--------------------------------------------------------------------
* FORM MSG_ADD
*--------------------------------------------------------------------
* Add the message to the log
*-------------------------------------------------------------------*
FORM msg_add.
  DATA:
  l_s_msg TYPE bal_s_msg.

* define data of message for Application Log
  l_s_msg-msgty = sy-msgty.
  l_s_msg-msgid = sy-msgid.
  l_s_msg-msgno = sy-msgno.
  l_s_msg-msgv1 = sy-msgv1.
  l_s_msg-msgv2 = sy-msgv2.
  l_s_msg-msgv3 = sy-msgv3.
  l_s_msg-msgv4 = sy-msgv4.

* add this message to log file
* (I_LOG_HANDLE is not specified, we want to add to the default log.
* If it does not exist we do not care =>EXCEPTIONS log_not_found = 0)
  CALL FUNCTION 'BAL_LOG_MSG_ADD'
  EXPORTING
* I_LOG_HANDLE =
  i_s_msg = l_s_msg
  EXCEPTIONS
  log_not_found = 0
  OTHERS = 1.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.

Using the function module:
In your ABAP program write the following code and use this function module ZIU_MESSAGE_LOGGING for logging.

Error rendering macro 'code': Invalid value specified for parameter 'com.atlassian.confluence.ext.code.render.InvalidValueException'
* Data declaration->
* Internal table for message logging
DATA: it_log_message TYPE STANDARD TABLE OF z_log_message,
wa_log_message TYPE z_log_message,
l_ext_number TYPE string.

Constants:
c_obj_zxiproxy TYPE balobj_d VALUE 'ZTESTLOG'.

* Now populate the internal table with the log messages as shown below. wa_log_message-
* msgty is the type of the message.
* E -> Error, W -> Warning, S -> Success

* Logging code for insert message into log
CLEAR wa_log_message.
wa_log_message-msgty = 'E'. " Can use W or S
wa_log_message-msg_text_1 = < Message text 1>.
wa_log_message-msg_text_2 = < Message text 2>
wa_log_message-msg_text_3 = < Message text 3>
wa_log_message-msg_text_4 = < Message text 4>

* Append the message into the internal table
APPEND wa_log_message TO it_log_message.

At the end transfer the log message to the system log by calling function module ZIU_MESSAGE_LOGGING. L_EXT_NUMBER will bt any string of your choice.

* Function module ZIU_MESSAGE_LOGGING will do the logging
* i_log_object is the object type (to be configrd using txn SLG0

CALL FUNCTION 'ZIU_MESSAGE_LOGGING'
EXPORTING
i_log_object = c_obj_zxiproxy
i_extnumber = l_ext_number
TABLES
t_log_message = it_log_message
EXCEPTIONS
log_header_inconsistent = 1
logging_error = 2
OTHERS = 3.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
ENDIF.

The logged messages can be viewed in transaction SLG1. For filtering the messages use the Object type.

5 Comments

  1. Unknown User (qep3xfy)

    Maybe additional the FM BAL_DSP_LOG_DISPLAY and in background the BAL_DSP_LOG_PRINT do a good job. By using this functions you can also inform the user about the entries, that will be written to the application log.

  2. FYI You don't need to create a custom structure to store the messages in - SAP has provided structure SYMSG for this purpose.

    Regards,
    Paul

  3. Unknown User (ueknvcz)

    If you have a registered namespace with the "/abc/" format, why can't you use it rather than the "x" or "y" names?

  4. Former Member

    Good Document.

    Thanks for you help & contribution.

  5. One of the problems we encountered was when the application log was committed in the same SAP LUW. After the BAL_DB_SAVE you need an implicit or explicit commit work. 

    If you write entries to the application log and the calling program issues a ROLLBACK WORK or crashes, the application log entries that have not been committed yet will be lost. And if you commit the application log by using explicit COMMIT WORK statement, the updates in the calling program are also committed.

    In the past, we solved this by using RFC DESTINATION 'NONE' or a HTTP call to force a separate LUW.

    As of WAS731, BAL_DB_SAVE has been extended with two parameters: i_2th_connection and  i_2th_connect_commit. You can use these to force a different LUW. I use them to commit application log entries directly so my trace is not lost.

    Note that you don't need to set up this second connection (trx DBACOCKPIT).