Below Code will read the Files in ZIP Folder Using Class cl_abap_zip.

 Using CL_ABAP_ZIP we can add multiple file to ZIP Folder and we can Read added files in ZIP.  

Get the File Content of type XSTRING from Upload UI Element and Pass it to Method LOAD of Class CL_ABAP_ZIP after creating instance of Class.  

DATA lo_zipobj TYPE REF TO cl_abap_zip.

CREATE OBJECT lo_zipobj.       " Instances of class

CALL METHOD lo_zipobj->load
  EXPORTING
    zip = lv_filecontent. " lv_filecontent is ZIP File Content of type XSTRING

*Attribute FILES will have number of files in the ZIP.
*Using Get file Method of class CL_ABAP_ZIP get the file content from ZIP and pass it to method READ as below.

LOOP AT lo_zipobj->files INTO ls_files.
  CALL METHOD lo_zipobj->get
    EXPORTING
      name    = ls_files-name
    IMPORTING
      content = lv_xstring.

  CALL METHOD cl_abap_conv_in_ce=>create
    EXPORTING
      input       = lv_xstring
      encoding    = 'UTF-8'
      replacement = '?'
      ignore_cerr = abap_true
    RECEIVING
      conv        = l_addr.

  CALL METHOD l_addr->read
    IMPORTING
      data = l_string.

ENDLOOP.
 

Each loop pass l_string will have ZIP Folder File Content 

This piece of code will help in uploading and downloading .txt or .csv  files from application server to presentation server and vice versa. 

*Text symbols:
*001 File Handling
*002 Path
*003 YES
*004 NO

*Selection Texts:
*P_CG3Y Download
*P_CG3Z Upload
*P_FILE Presentation Server Path
*P_FILE1 Presentation Server Path
*P_O_WRIT Overwrite the file ?
*P_PATH Application Server Path
*P_PATH1 Application Server Path

*&---------------------------------------------------------------------*
*& Report  Z_CG3_Z_Y
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
REPORT  z_cg3_z_y NO STANDARD PAGE HEADING.
CONSTANTS : c_m1(2) TYPE c VALUE 'M1',
            c_m2(2) TYPE c VALUE 'M2',
            c_m3(2) TYPE c VALUE 'M3',
            c_m4(2) TYPE c VALUE 'M4',
            c_x(1)  TYPE c VALUE 'X'.
DATA : w_path TYPE sapb-sappfad,
       w_file TYPE sapb-sappfad.
DATA  w_ans(1) TYPE c.
DATA : BEGIN OF t_data OCCURS 0,
       data(3000) TYPE c,
       END OF t_data.
SELECTION-SCREEN : BEGIN OF BLOCK ss01 WITH FRAME TITLE text-001.
PARAMETERS : p_cg3z RADIOBUTTON GROUP g1 USER-COMMAND flag DEFAULT 'X' ,
             p_cg3y RADIOBUTTON GROUP g1 .
SELECTION-SCREEN : BEGIN OF BLOCK ss02 WITH FRAME TITLE text-002.
PARAMETERS : p_file TYPE rlgrap-filename  DEFAULT 'D:\test.csv' MODIF ID m1.
PARAMETERS : p_path TYPE rlgrap-filename DEFAULT '/tmp/test'    MODIF ID m1.
PARAMETERS : p_path1(60) TYPE c DEFAULT '/tmp/test'             MODIF ID m2.
PARAMETERS : p_file1 TYPE rlgrap-filename DEFAULT 'D:\test.txt' MODIF ID m2.
SELECTION-SCREEN : END OF BLOCK ss02.
SKIP 2.
SELECTION-SCREEN : BEGIN OF  LINE.
SELECTION-SCREEN : POSITION 60.
PARAMETERS : p_o_writ AS CHECKBOX MODIF ID m1.
SELECTION-SCREEN: COMMENT 62(15) text1 MODIF ID m1.
SELECTION-SCREEN : END OF LINE.
SELECTION-SCREEN : END OF BLOCK ss01.

AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF p_cg3z EQ c_x AND screen-group1 EQ c_m2.
      screen-active = 0.
    ENDIF.
    IF p_cg3y EQ c_x AND screen-group1 EQ c_m1.
      screen-active = 0.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  DATA: t_file_tab TYPE filetable,
        w1 LIKE LINE OF t_file_tab,
        w_rc TYPE i.
  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      default_extension       = 'CSV'
    CHANGING
      file_table              = t_file_tab
      rc                      = w_rc
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc = 0.
*    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
*               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  READ TABLE t_file_tab INTO w1 INDEX 1.
  IF sy-subrc = 0.
    p_file = w1-filename.
  ENDIF.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file1.
  DATA: t_file_tab TYPE filetable,
        w1 LIKE LINE OF t_file_tab,
        w_rc TYPE i.
  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      default_extension       = 'CSV'
    CHANGING
      file_table              = t_file_tab
      rc                      = w_rc
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc = 0.
*    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
*               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  READ TABLE t_file_tab INTO w1 INDEX 1.
  IF sy-subrc = 0.
    p_file1 = w1-filename.
  ENDIF.

INITIALIZATION .
  text1 = 'Overwrite File'.

START-OF-SELECTION.
  IF  p_cg3z EQ c_x.
    TRANSLATE : p_path  TO LOWER CASE,
                p_path1 TO LOWER CASE,
                p_file  TO LOWER CASE,
                p_file1 TO LOWER CASE.
    IF p_o_writ EQ ' '.
      OPEN DATASET p_path FOR INPUT IN BINARY MODE.
      IF sy-subrc EQ 0.
        CLEAR : w_ans.
        CALL FUNCTION 'POPUP_TO_CONFIRM'
          EXPORTING
            titlebar              = 'CONFIRMATION POP-UP '
            text_question         = 'Are You Sure You WAnt to Over Write The File'
            text_button_1         = 'YES'
            text_button_2         = 'NO'
            display_cancel_button = c_x
            start_column          = 25
            start_row             = 6
          IMPORTING
            answer                = w_ans.
        IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
        ENDIF.
        IF w_ans = '1'.
          CLOSE DATASET p_path.
          PERFORM f_upload_download .
        ELSEIF w_ans = '2'.
          CLOSE DATASET p_path.
          EXIT.
        ELSEIF w_ans = 'A'.
          CLOSE DATASET p_path.
          EXIT.
        ENDIF.
      ELSE.
        CLOSE DATASET p_path.
        PERFORM f_upload_download .
        w_ans = '1'.
      ENDIF.
      CLOSE DATASET p_path.
    ELSE.
      PERFORM f_upload_download .
    ENDIF.
  ELSE.  " for dwonload p_cg3y
    PERFORM f_upload_download .
  ENDIF.
  IF p_cg3z EQ c_x.
    DATA : w_filename TYPE string.
    MOVE p_file TO w_filename.
    CALL FUNCTION 'GUI_UPLOAD'
      EXPORTING
        filename = w_filename
      TABLES
        data_tab = t_data.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ELSE.
    TRANSLATE p_path1 TO LOWER CASE.
    OPEN DATASET p_path1 FOR INPUT IN TEXT MODE ENCODING DEFAULT.
    DO.
      IF sy-subrc <> 0.
        EXIT.
      ENDIF.
      READ DATASET p_path1 INTO t_data .
      APPEND t_data.
      CLEAR t_data.
    ENDDO.
    CLOSE DATASET p_path1.
  ENDIF.

END-OF-SELECTION.
  IF w_ans    EQ '1' OR
     p_o_writ EQ 'X'.
    WRITE : / 'File contents:'.
    SKIP 1.
    LOOP AT t_data.
      WRITE : t_data-data.
    ENDLOOP.
  ENDIF.
*&---------------------------------------------------------------------*
*&      Form  F_UPLOAD_DOWNLOAD
*&---------------------------------------------------------------------*
FORM f_upload_download .
  IF p_cg3z EQ c_x.
    TRANSLATE p_path TO LOWER CASE.
    MOVE p_path TO w_path .
    MOVE p_file TO w_file.
    CALL FUNCTION 'ARCHIVFILE_CLIENT_TO_SERVER'
      EXPORTING
        path       = w_file
        targetpath = w_path
      EXCEPTIONS
        error_file = 1
        OTHERS     = 2.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ELSE .
      MESSAGE 'successfully transfered' TYPE 'S'.
    ENDIF.
  ELSE.
    TRANSLATE : p_path1 TO LOWER CASE,
               p_file1 TO LOWER CASE.
    MOVE p_path1 TO w_path .
    MOVE p_file1 TO w_file.
    CALL FUNCTION 'ARCHIVFILE_SERVER_TO_CLIENT'
      EXPORTING
        path       = w_path
        targetpath = w_file
      EXCEPTIONS
        error_file = 1
        OTHERS     = 2.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ELSE.
      MESSAGE 'successfully transfered' TYPE 'S' .
    ENDIF.
  ENDIF.
ENDFORM.                    " F_UPLOAD_DOWNLOAD
 

Use the Function : 
C13Z_APPL_TO_FRONT_END to download the data from the Application server to Presentation.

This has to be restricted due to the functionality for the user can download any file to PC. So the file name has to be checked to restrict the user downloading any file to his PC. 

Kind Regards,
Senthilraj Selvaraj 

Author: Raghavendra AY

Submitted: February 15, 2007

Since it's not possible to download data to presentation server in background, we first download the data to application server file, then read this application server file and save it to presentation server in foreground, which ideally means each such download program requires another program which takes the file structure into consideration and download it to presentation server.

This code can be used to download data from files on application server to presentation server in foreground

To download data from Application server files to presentation server

Upload / Download / Delete functionality of Application server Program.

REPORT zapplserver MESSAGE-ID fb.
************************************************************************
* Constants
CONSTANTS:c_mask(80) TYPE c VALUE ',.,..', " Mask
          c_file_type(10) TYPE c VALUE 'ASC', " File type
          c_mode(1) TYPE c VALUE 'L'. " Mode
* Internal tables *
DATA: BEGIN OF i_file OCCURS 0,
        field(3000) TYPE c,
      END OF i_file.
DATA :
v_msg(100),
struct_file LIKE i_file OCCURS 0.

* Parameters
PARAMETERS: p_fpath TYPE draw-filep OBLIGATORY,
            p_lpath TYPE localfile,
            p_upload AS CHECKBOX DEFAULT 'X',
            p_dload AS CHECKBOX,
            p_delete AS CHECKBOX.
************************************************************************
* Check selection-screen entries *
************************************************************************
* At selection screen
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_lpath.
  PERFORM get_file CHANGING p_lpath.
************************************************************************
* Main *
************************************************************************
* Start of selection
START-OF-SELECTION.
  IF p_upload = 'X'.
* Upload to app server
    PERFORM upload_to_appserver.
  ENDIF.
  IF p_dload = 'X'.
* Download to desktop
    PERFORM download_to_desktop.
  ENDIF.
  IF p_delete = 'X'.
* Delete file on app server
    DELETE DATASET p_fpath.
    IF sy-subrc = 0.
      MESSAGE s000 WITH 'File deleted'.
    ENDIF.
  ENDIF.
************************************************************************
* OUTPUT of extracted data *
************************************************************************
* sort.
* loop.
*
* endloop.
************************************************************************
* EVENTS DURING LISTPROCESSING *
************************************************************************
************************************************************************
* EVENTS AT USER COMMAND
************************************************************************
*at line selection.
*at user-command.
************************************************************************
* ROUTINES/FORM *
************************************************************************
*-------------------------------------------------------------
* Set file path of local machine
*-------------------------------------------------------------
FORM get_file CHANGING file_out.
  DATA: l_filename TYPE localfile. "Local file for upload/download
  CALL FUNCTION 'WS_FILENAME_GET'
    EXPORTING
      mask             = c_mask
      mode             = c_mode
    IMPORTING
      filename         = l_filename
    EXCEPTIONS
      inv_winsys       = 01
      no_batch         = 02
      selection_cancel = 03
      selection_error  = 04.
  p_lpath = l_filename.
ENDFORM.                    "get_file
*&---------------------------------------------------------------------*
*& Form UPLOAD_TO_APPSERVER
*&---------------------------------------------------------------------*
* Upload local file to app server
*----------------------------------------------------------------------*
FORM upload_to_appserver .
  DATA: l_lpath TYPE string.
  l_lpath = p_lpath.
  REFRESH i_file.
  CLEAR i_file.

  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename                = l_lpath
      filetype                = c_file_type
    TABLES
      data_tab                = i_file
    EXCEPTIONS
      file_open_error         = 1
      file_read_error         = 2
      no_batch                = 3
      gui_refuse_filetransfer = 4
      invalid_type            = 5
      no_authority            = 6
      unknown_error           = 7
      bad_data_format         = 8
      header_not_allowed      = 9
      separator_not_allowed   = 10
      header_too_long         = 11
      unknown_dp_error        = 12
      access_denied           = 13
      dp_out_of_memory        = 14
      disk_full               = 15
      dp_timeout              = 16
      OTHERS                  = 17.

  OPEN DATASET p_fpath FOR OUTPUT IN TEXT MODE ENCODING DEFAULT
  MESSAGE v_msg.
  IF sy-subrc = 0.
    LOOP AT i_file. " into struct_file.
      IF NOT i_file IS INITIAL.
        TRANSFER i_file TO p_fpath.
      ENDIF.
    ENDLOOP.
  ELSE.
    MESSAGE e000 WITH 'File cannot be opened for output'.
  ENDIF.
  CLOSE DATASET p_fpath.
ENDFORM. " UPLOAD_TO_APPSERVER
*&---------------------------------------------------------------------*
*& Form DOWNLOAD_TO_DESKTOP
*&---------------------------------------------------------------------*
FORM download_to_desktop .
  OPEN DATASET p_fpath FOR INPUT IN TEXT MODE
  ENCODING DEFAULT
  MESSAGE v_msg.
  IF sy-subrc = 0.
    REFRESH : i_file.
    DO.
      READ DATASET p_fpath INTO i_file.
      IF sy-subrc = 0.
        APPEND i_file TO i_file.
      ELSE.
        EXIT.
      ENDIF.
    ENDDO.
  ELSE.
    MESSAGE e000 WITH 'File cannot be opened'.
  ENDIF.
  CLOSE DATASET p_fpath.

  CALL FUNCTION 'DOWNLOAD'
    EXPORTING
      filename = p_lpath
    TABLES
      data_tab = i_file.
ENDFORM. " DOWNLOAD_TO_DESKTOP

REPORT z_arch_move NO STANDARD PAGE HEADING
                      LINE-SIZE 132.
************************************************************************
* Move a file from source to target directories or Delete file
*
* This program will not run in a productive client.
*
* Source and target may be either on the Presentation or Application
* servers.
*
* You can only copy if either source or target is on the Presentation
* server.
* You can either copy or move if both source and target are on the
* Application server.
*
* When copying, provide the complete file specification for both
* source and target.
*
* I had trouble getting the OS commands to accept an application server
* filespec containing spaces. So there's a warning if you use one. Be
* aware that the operation may not succeed regardless of the program
* messages.
************************************************************************
* Tables
************************************************************************

************************************************************************
* Types
************************************************************************
TYPE-POOLS: abap.

TYPES: BEGIN OF ty_data,
         rec                 TYPE string,
       END OF ty_data.
TYPES: tyt_data              TYPE STANDARD TABLE OF ty_data.

************************************************************************
* Classes
************************************************************************
CLASS cl_gui_frontend_services DEFINITION LOAD.

************************************************************************
* Data
************************************************************************
DATA: w_answer               TYPE char1,
      w_rc                   TYPE i.

DATA: BEGIN OF w_flag,
        stop                 TYPE flag,
      END OF w_flag.

DATA: t_data                 TYPE tyt_data.

************************************************************************
* Selection screen
************************************************************************
* Customising - change the first block to reflect your requirements.
*               Set the "modif id" to "OUT" to make a field output-only
*               or to "HID" to hide it completely.

* Data selections
*****************
SELECTION-SCREEN: BEGIN OF BLOCK zselections WITH FRAME.
* Action
SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
*   Move or Copy
PARAMETERS: p_xfer  RADIOBUTTON GROUP zg1 DEFAULT 'X'.
*   Delete
PARAMETERS: p_dele  RADIOBUTTON GROUP zg1.
SELECTION-SCREEN: END OF BLOCK b1.

* Source
SELECTION-SCREEN: BEGIN OF BLOCK b2 WITH FRAME TITLE text-002.
*   Presentation server
PARAMETERS: p_s_pc  RADIOBUTTON GROUP zg2 DEFAULT 'X'.
*   Application server
PARAMETERS: p_s_as  RADIOBUTTON GROUP zg2.
*   File name
PARAMETERS: p_sfile TYPE localfile.
SELECTION-SCREEN: END OF BLOCK b2.

* Target (Move or Copy only)
SELECTION-SCREEN: BEGIN OF BLOCK b3 WITH FRAME TITLE text-003.
*   Presentation server
PARAMETERS: p_t_pc  RADIOBUTTON GROUP zg3.
*   Application server
PARAMETERS: p_t_as  RADIOBUTTON GROUP zg3 DEFAULT 'X'.
*   File name
PARAMETERS: p_tfile TYPE localfile.

*   Between Application servers
SELECTION-SCREEN: BEGIN OF BLOCK b4 WITH FRAME TITLE text-004.
*     Move
PARAMETERS: p_move  RADIOBUTTON GROUP zg4 DEFAULT 'X'.
*     Copy
PARAMETERS: p_copy  RADIOBUTTON GROUP zg4.
SELECTION-SCREEN: END OF BLOCK b4.

SELECTION-SCREEN: END OF BLOCK b3.

SELECTION-SCREEN: END OF BLOCK zselections.

************************************************************************
* Events
************************************************************************
INITIALIZATION.
  PERFORM not_in_production.

AT SELECTION-SCREEN ON BLOCK zselections.
  PERFORM check_selections.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_sfile.
  PERFORM choose_filename USING 'P_SFILE'
                                'P_S_PC'.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_tfile.
  PERFORM choose_filename USING 'P_TFILE'
                                'P_T_PC'.

START-OF-SELECTION.
  PERFORM determine_actions.

END-OF-SELECTION.
  PERFORM stop_if_requested.

************************************************************************
* Forms
************************************************************************

************************************************************************
FORM check_selections.
************************************************************************
  DATA: l_tempfile TYPE localfile.

* Need a source file
  IF p_sfile IS INITIAL.
    MESSAGE e899(fi) WITH 'Source must be specified'.
  ENDIF.

* Need a target file for Move or Copy
  IF  p_xfer  EQ abap_true
  AND p_tfile IS INITIAL.
    MESSAGE e899(fi) WITH 'Target must be specified'.
  ENDIF.

* Check for spaces in source or target
  IF p_s_as EQ abap_true.
    l_tempfile = p_sfile.
    CONDENSE l_tempfile NO-GAPS.
    IF l_tempfile NE p_sfile.
      MESSAGE w899(fi) WITH 'Spaces in source file name'.
    ENDIF.
  ENDIF.

  IF p_t_as EQ abap_true.
    l_tempfile = p_tfile.
    CONDENSE l_tempfile NO-GAPS.
    IF l_tempfile NE p_tfile.
      MESSAGE w899(fi) WITH 'Spaces in target file name'.
    ENDIF.
  ENDIF.

ENDFORM.                    "check_selections

************************************************************************
FORM choose_filename USING px_field_filename LIKE dynpread-fieldname
                           px_field_pcflag   LIKE dynpread-fieldname.
************************************************************************
  DATA: l_location LIKE dxfields-location.

  DATA: lt_dynp    TYPE STANDARD TABLE OF dynpread,
        l_dynp     TYPE dynpread.

  l_dynp-fieldname = px_field_pcflag.
  APPEND l_dynp TO lt_dynp.
  CALL FUNCTION 'DYNP_VALUES_READ'
    EXPORTING
      dyname     = sy-cprog
      dynumb     = sy-dynnr
    TABLES
      dynpfields = lt_dynp
    EXCEPTIONS
      OTHERS     = 11.
  IF sy-subrc <> 0.
    MESSAGE e899(fi) WITH 'Error (1) reading selection screen'.
  ENDIF.

  READ TABLE lt_dynp INDEX 1 INTO l_dynp.
  IF sy-subrc EQ 0.
    IF l_dynp-fieldvalue EQ abap_true.
      l_location = 'P'.
    ELSE.
      l_location = 'A'.
    ENDIF.
  ELSE.
    MESSAGE e899(fi) WITH 'Error (2) reading selection screen'.
  ENDIF.

  CALL FUNCTION 'F4_DXFILENAME_4_DYNP'
    EXPORTING
      dynpfield_filename = px_field_filename
      dyname             = sy-cprog
      dynumb             = sy-dynnr
      filetype           = 'P'
      location           = l_location
      server             = ' '.

ENDFORM.                    "choose_filename

************************************************************************
FORM confirm_delete_file.
************************************************************************
  CALL FUNCTION 'POPUP_TO_CONFIRM'
    EXPORTING
      text_question         = 'Do you really want to delete this file?'
      display_cancel_button = abap_false
    IMPORTING
      answer                = w_answer
    EXCEPTIONS
      text_not_found        = 1
      OTHERS                = 2.
  IF sy-subrc NE 0
  OR w_answer NE 1.
    w_flag-stop = abap_true.
    MESSAGE s899(fi) WITH 'Deletion not attempted'.
    STOP.
  ENDIF.

ENDFORM.                    "confirm_delete_file

************************************************************************
FORM copy_file_on_pres_srvr USING px_source TYPE localfile
                                  px_target TYPE localfile.
************************************************************************
  DATA: l_sfile TYPE string,
        l_tfile TYPE string.

  l_sfile = px_source.
  l_tfile = px_target.
  CALL METHOD cl_gui_frontend_services=>file_copy
    EXPORTING
      source      = l_sfile
      destination = l_tfile
      overwrite   = abap_true
    EXCEPTIONS
      OTHERS      = 13.
  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully copied file', px_source,
           / 'to',                       px_target UNDER px_source.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Failed to copy file' px_source
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.
ENDFORM.                    "copy_file_on_pres_srvr

************************************************************************
FORM delete_file.
************************************************************************
  DATA: l_file TYPE string.

  IF p_s_pc EQ abap_true.
*   Delete Presentation server file
    l_file = p_sfile.
    CALL METHOD cl_gui_frontend_services=>file_delete
      EXPORTING
        filename             = l_file
      CHANGING
        rc                   = w_rc
      EXCEPTIONS
        file_delete_failed   = 1
        cntl_error           = 2
        error_no_gui         = 3
        file_not_found       = 4
        access_denied        = 5
        unknown_error        = 6
        not_supported_by_gui = 7
        wrong_parameter      = 8
        OTHERS               = 9.
  ELSE.
*   Delete Application server file
    CATCH SYSTEM-EXCEPTIONS file_access_errors = 4.
      DELETE DATASET p_sfile.
    ENDCATCH.
  ENDIF.

  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully deleted file', p_sfile.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Failed to delete file' p_sfile
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.

ENDFORM.                    "delete_file

************************************************************************
FORM determine_actions.
************************************************************************
  IF p_xfer EQ abap_true.
    PERFORM move_or_copy.
  ELSE.
    PERFORM confirm_delete_file.
    PERFORM delete_file.
  ENDIF.

ENDFORM.                    "determine_actions

************************************************************************
FORM move_file_on_app_srvr USING px_source TYPE localfile
                                 px_target TYPE localfile.
************************************************************************
  DATA: l_exitcode  TYPE btcxpgexit,
        l_parms     TYPE btcxpgpar,
        l_status    TYPE btcxpgstat.

  DATA: lt_protocol TYPE STANDARD TABLE OF btcxpm,
        l_protocol  TYPE btcxpm.

  CONCATENATE px_source
              px_target
         INTO l_parms
              SEPARATED BY space.
* External command:
* - Unix    - mv
* - Windows - cmd /c move
  CALL FUNCTION 'SXPG_COMMAND_EXECUTE'
    EXPORTING
      commandname                   = 'Z_ARCH_MV'
      additional_parameters         = l_parms
    IMPORTING
      status                        = l_status
      exitcode                      = l_exitcode
    TABLES
      exec_protocol                 = lt_protocol
    EXCEPTIONS
      no_permission                 = 1
      command_not_found             = 2
      parameters_too_long           = 3
      security_risk                 = 4
      wrong_check_call_interface    = 5
      program_start_error           = 6
      program_termination_error     = 7
      x_error                       = 8
      parameter_expected            = 9
      too_many_parameters           = 10
      illegal_command               = 11
      wrong_asynchronous_parameters = 12
      cant_enq_tbtco_entry          = 13
      jobcount_generation_error     = 14
      OTHERS                        = 15.
  IF sy-subrc   NE 0
  OR l_status   NE 'O'
  OR l_exitcode NE '0'.
*   Failure
    FORMAT COLOR COL_NEGATIVE.
    WRITE: / 'Failed to move' , px_source,
           / 'to',              px_target UNDER px_source.
    FORMAT COLOR COL_NORMAL.
    LOOP AT lt_protocol INTO l_protocol.
      WRITE: / l_protocol-message+0(l_protocol-length).
    ENDLOOP.
  ELSE.
*   Success
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully moved' , px_source,
           / 'to',                  px_target UNDER px_source.
  ENDIF.

ENDFORM.                    "move_file_on_app_srvr

************************************************************************
FORM move_or_copy.
************************************************************************
  IF  p_s_as EQ abap_true
  AND p_t_as EQ abap_true.
*   Source and Target both on AppSrvr
    IF p_move EQ abap_true.
      PERFORM move_file_on_app_srvr USING p_sfile
                                          p_tfile.
    ELSE.
      PERFORM read_appsrvr_file USING p_sfile
                           CHANGING t_data.
      PERFORM write_appsrvr_file USING p_tfile
                                       t_data.
    ENDIF.
  ELSEIF p_s_pc EQ abap_true
  AND    p_t_pc EQ abap_true.
*   Source and Target both on PresSrvr
    PERFORM copy_file_on_pres_srvr USING p_sfile
                                         p_tfile.
  ELSEIF p_s_pc EQ abap_true.
*   Source on PresSrvr; Target on AppSrvr
    PERFORM read_local_file USING p_sfile
                         CHANGING t_data.
    PERFORM write_appsrvr_file USING p_tfile
                                     t_data.
  ELSE.
*   Source on AppSrvr; Target on PresSrvr
    PERFORM read_appsrvr_file USING p_sfile
                         CHANGING t_data.
    PERFORM write_local_file USING p_tfile
                                   t_data.
  ENDIF.

ENDFORM.                    "move_or_copy

************************************************************************
FORM not_in_production.
************************************************************************
  DATA: l_cccategory TYPE cccategory.

  SELECT SINGLE cccategory INTO l_cccategory
         FROM t000
         WHERE mandt EQ sy-mandt.
  IF l_cccategory EQ 'P'.
    MESSAGE e899(fi)
            WITH 'Program' sy-repid
                 'is not available in Production clients'.
  ENDIF.

ENDFORM.                    "not_in_production

************************************************************************
FORM read_appsrvr_file USING px_source TYPE localfile
                    CHANGING pxt_data  TYPE tyt_data.
************************************************************************
  DATA: l_data TYPE ty_data.

  CATCH SYSTEM-EXCEPTIONS file_access_errors = 4.
    OPEN DATASET px_source FOR INPUT IN TEXT MODE.
    DO.
      READ DATASET px_source INTO l_data-rec.
      IF sy-subrc NE 0.
        EXIT.
      ENDIF.
      APPEND l_data TO pxt_data.
    ENDDO.
    CLOSE DATASET px_source.
  ENDCATCH.
  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully read', px_source.
    FORMAT COLOR COL_NORMAL.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Unable to read AppSrvr file' px_source
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.

ENDFORM.                    "read_appsrvr_file

************************************************************************
FORM read_local_file USING px_source TYPE localfile
                  CHANGING pxt_data  TYPE tyt_data.
************************************************************************
  DATA: l_file TYPE string.

  l_file = px_source.
  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename = l_file
    TABLES
      data_tab = pxt_data
    EXCEPTIONS
      OTHERS   = 17.
  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully read', px_source.
    FORMAT COLOR COL_NORMAL.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Unable to read local file' px_source
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.

ENDFORM.                    "read_local_file

************************************************************************
FORM stop_if_requested.
************************************************************************
  IF w_flag-stop EQ abap_true.
    STOP.
  ENDIF.

ENDFORM.                    "stop_if_requested

************************************************************************
FORM write_appsrvr_file USING px_target TYPE localfile
                              pxt_data  TYPE tyt_data.
************************************************************************
  DATA: l_data TYPE ty_data.

  CATCH SYSTEM-EXCEPTIONS file_access_errors = 4.
    OPEN DATASET px_target FOR OUTPUT IN TEXT MODE.
    LOOP AT pxt_data INTO l_data.
      TRANSFER l_data-rec TO px_target.
    ENDLOOP.
    CLOSE DATASET px_target.
  ENDCATCH.
  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully written', px_target.
    FORMAT COLOR COL_NORMAL.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Unable to write AppSrvr file' px_target
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.

ENDFORM.                    "write_appsrvr_file

************************************************************************
FORM write_local_file USING px_target TYPE localfile
                            pxt_data  TYPE tyt_data.
************************************************************************
  DATA: l_file TYPE string.

  l_file = px_target.
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename = l_file
    TABLES
      data_tab = pxt_data
    EXCEPTIONS
      OTHERS   = 17.
  IF sy-subrc EQ 0.
    FORMAT COLOR COL_POSITIVE.
    WRITE: / 'Successfully written', px_target.
    FORMAT COLOR COL_NORMAL.
  ELSE.
    w_flag-stop = abap_true.
    MESSAGE s899(fi)
            WITH 'Unable to write local file' px_target
            DISPLAY LIKE 'E'.
    STOP.
  ENDIF.

ENDFORM.                    "write_local_file

REPORT z_appl_presentation_server NO STANDARD PAGE HEADING .
*&----------------DATA DECLARATION----------------------------------&
INCLUDE z_appl_presentation_server_data_declaration.
*&----------------INCLUDE FOR PERFORMS------------------------------&*
INCLUDE z_appl_presentation_server_forms.
*&----------------AT SELECTION SCREEN EVENT-------------------------&*
*& At selection screen output for screen attributes
AT SELECTION-SCREEN OUTPUT.
  PERFORM screen_attributes.
*& Providing f4 help path to filmanager on presentation server
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
  PERFORM source_destination.
*& Providing f4 help path to Application server
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file1.
  PERFORM application_server_path.
*&----------------START OF SELECTION--------------------------------&*
START-OF-SELECTION.
*& Reading data from application server and copy it to presentation server
  IF p_read = 'X'.
    PERFORM read_from_server.
*& Copy the data from presentation server and write to application server
  ELSE.
    PERFORM write_to_server.
  ENDIF.
*&---------------------------------------------------------------------*
*& Include z_appl_presentation_server_DATA_DECLARATION
*&---------------------------------------------------------------------*
*& Types Declaration
  TYPES : BEGIN OF ty_bseg, "Accounting Document Segment
            bukrs(4), "Company Code
            belnr(10), "Accounting Document Number
            gjahr(4), "Fiscal Year
            buzei(3), "Number of Line Item Within Accounting Document
            kostl(10), "Cost Center
            saknr(10), "G/L Account No
          END OF ty_bseg.
*& Work area and Internal tabel
  DATA: wa_bseg TYPE ty_bseg,
        it_bseg TYPE STANDARD TABLE OF ty_bseg.
*& Data declaratio for read/write data to application serve
  DATA: d_filename(128),
        file TYPE string.
*& Selection Screen
  PARAMETERS: p_read RADIOBUTTON GROUP rad1 DEFAULT 'X' "Copy the file from Application server to PC
                      USER-COMMAND chek,
              p_write RADIOBUTTON GROUP rad1, "Copy the file from PC to Application server
              p_file LIKE rlgrap-filename OBLIGATORY
                     DEFAULT 'C:\Documents and Settings\pvora\Desktop\test.txt'
                     MODIF ID g02, "Filename on PC
              p_file1 LIKE rlgrap-filename DEFAULT '.\Pratik.txt' "Filename on server
                      MODIF ID g01.
*&---------------------------------------------------------------------*
*& Include z_appl_presentation_server_FORMS
*&---------------------------------------------------------------------*
*&---------------------------------------------------------------------*
*& Form read_from_server
*&---------------------------------------------------------------------*
FORM read_from_server.
  CLEAR d_filename.
  d_filename = p_file1.
*& Reading file from application server
  OPEN DATASET d_filename FOR INPUT IN TEXT MODE ENCODING DEFAULT.
  DO.
    READ DATASET d_filename INTO wa_bseg.
    IF sy-subrc <> 0.
      EXIT.
    ENDIF.
    APPEND wa_bseg TO it_bseg.
  ENDDO.
  CLOSE DATASET d_filename.
*& Dwonloading file to Presentation Server
  file = p_file.
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                = file
      filetype                = 'ASC'
      append                  = ' '
    TABLES
      data_tab                = it_bseg
    EXCEPTIONS
      file_write_error        = 1
      no_batch                = 2
      gui_refuse_filetransfer = 3
      invalid_type            = 4
      no_authority            = 5
      unknown_error           = 6
      header_not_allowed      = 7
      separator_not_allowed   = 8
      filesize_not_allowed    = 9
      header_too_long         = 10
      dp_error_create         = 11
      dp_error_send           = 12
      dp_error_write          = 13
      unknown_dp_error        = 14
      access_denied           = 15
      dp_out_of_memory        = 16
      disk_full               = 17
      dp_timeout              = 18
      file_not_found          = 19
      dataprovider_exception  = 20
      control_flush_error     = 21.
ENDFORM. " read_from_server
*&---------------------------------------------------------------------*
*& Form write_to_server
*&---------------------------------------------------------------------*
FORM write_to_server.
*& Uploading file from Presentation server
  file = p_file.
  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename                = file
      filetype                = 'ASC'
    TABLES
      data_tab                = it_bseg
    EXCEPTIONS
      file_open_error         = 1
      file_read_error         = 2
      no_batch                = 3
      gui_refuse_filetransfer = 4
      invalid_type            = 5
      no_authority            = 6
      unknown_error           = 7
      bad_data_format         = 8
      header_not_allowed      = 9
      separator_not_allowed   = 10
      header_too_long         = 11
      unknown_dp_error        = 12
      access_denied           = 13
      dp_out_of_memory        = 14
      disk_full               = 15
      dp_timeout              = 16.
  CLEAR d_filename.
  d_filename = p_file1.
*& Writing in the file on application server
  OPEN DATASET d_filename FOR OUTPUT IN TEXT MODE ENCODING DEFAULT.
  LOOP AT it_bseg INTO wa_bseg.
    TRANSFER wa_bseg TO d_filename.
  ENDLOOP.
  CLOSE DATASET d_filename.
  OPEN DATASET d_filename FOR INPUT IN TEXT MODE ENCODING DEFAULT.
  DO.
    READ DATASET d_filename INTO wa_bseg.
    IF sy-subrc <> 0.
      EXIT.
    ENDIF.
    WRITE:/ wa_bseg-bukrs, wa_bseg-belnr, wa_bseg-gjahr, wa_bseg-kostl, wa_bseg-saknr.
  ENDDO.
  CLOSE DATASET d_filename.
ENDFORM. " write_to_server
*&---------------------------------------------------------------------*
*& Form source_destination
*&---------------------------------------------------------------------*
FORM source_destination.
  file = p_file.
  CALL FUNCTION 'KD_GET_FILENAME_ON_F4'
    EXPORTING
      program_name  = syst-repid
      dynpro_number = syst-dynnr
      field_name    = p_file
*     STATIC        = ' '
*     MASK          = ' '
    CHANGING
      file_name     = p_file
    EXCEPTIONS
      mask_too_long = 1.
ENDFORM. " source_destination
*&---------------------------------------------------------------------*
*& Form application_server_path
*&---------------------------------------------------------------------*
FORM application_server_path.
  IF p_read = 'X'.
*& Selecting file from server on pressing f4
    CALL FUNCTION '/SAPDMC/LSM_F4_SERVER_FILE'
      EXPORTING
        directory        = '.\'
        filemask         = ' '
      IMPORTING
        serverfile       = p_file1
      EXCEPTIONS
        canceled_by_user = 1.
  ELSE.
    MESSAGE 'F4 is only valid for transfering data from Server to PC' TYPE 'S'.
  ENDIF.
ENDFORM. " application_server_path
*&---------------------------------------------------------------------*
*& Form screen_attributes
*&---------------------------------------------------------------------*
FORM screen_attributes .
  IF p_write = 'X'.
    LOOP AT SCREEN.
      IF screen-group1 = 'G01'.
        screen-input = 0.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
  ELSE.
    LOOP AT SCREEN.
      IF screen-group1 = 'G02'.
        screen-input = 0.
        MODIFY SCREEN.
      ENDIF.
    ENDLOOP.
  ENDIF.
ENDFORM. " screen_attributes

File on presentation server

Solution for any ABAP system

Parameters of F4_DXFILENAME_4_DYNP:

• filetype:

  • 'P' represents Physical file name

  • 'L' represents Logical file name.

• location:

  • 'A' represents Application Server

  • 'P' represents Presentation server.

PARAMETERS p_file TYPE dxfile-filename.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

CALL FUNCTION 'F4_DXFILENAME_4_DYNP'
 EXPORTING
      dynpfield_filename = 'P_FILE'
      dyname             = sy-repid
      dynumb             = sy-dynnr
      filetype           = 'P'
      location           = 'A'
      server             = '  '.

Solution for SAP ERP only

With the function module F4_FILENAME.

REPORT zvenkattest.

*------------------------------------------------------------*
* selection screen parameters
*------------------------------------------------------------*
PARAMETERS: p_source LIKE rlgrap-filename.

*------------------------------------------------------------*
* at selection screen for field
*------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_source .
  CALL FUNCTION 'F4_FILENAME'
    EXPORTING
      program_name  = syst-cprog
      dynpro_number = syst-dynnr
      field_name    = 'P_SOURCE'
    IMPORTING
      file_name     = p_source.

File on application server

Parameters of F4_DXFILENAME_4_DYNP:

• filetype:

  • 'P' represents Physical file name

  • 'L' represents Logical file name.

• location:

  • 'A' represents Application Server

  • 'P' represents Presentation server.

PARAMETERS p_file TYPE dxfile-filename.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

CALL FUNCTION 'F4_DXFILENAME_4_DYNP'
 EXPORTING
      dynpfield_filename = 'P_FILE'
      dyname             = sy-repid
      dynumb             = sy-dynnr
      filetype           = 'P'
      location           = 'A'
      server             = '  '.

Get Name of Files in Excel File from Selected Directory of Local System

REPORT  zfsl_gdirfn.

************************************************************************
*             Declaration of Variables & Internal Tables               *
************************************************************************
DATA: it_file LIKE STANDARD TABLE OF sdokpath WITH HEADER LINE,
      it_dir  LIKE STANDARD TABLE OF sdokpath WITH HEADER LINE,
      file_count TYPE i,
      dir_count TYPE i.

************************************************************************
*                          Selection Screen                            *
************************************************************************
SELECTION-SCREEN: BEGIN OF BLOCK a WITH FRAME TITLE ftitle,
                  BEGIN OF LINE,
                  COMMENT 1(40) lpdirp FOR FIELD pdirp.
PARAMETER:  pdirp TYPE pfeflnamel OBLIGATORY. " Directory Path from where you want to get Name of Files
SELECTION-SCREEN: END OF LINE,
                  BEGIN OF LINE,
                  COMMENT 1(40) lpsavep FOR FIELD psavep.
PARAMETER:  psavep TYPE string OBLIGATORY. " Excel File Path and Name in which you want to Save Name of Files
SELECTION-SCREEN: END OF LINE,
                  END OF BLOCK a.

************************************************************************
*                          START-OF-SELECTION                          *
************************************************************************
START-OF-SELECTION.

  CALL FUNCTION 'TMP_GUI_DIRECTORY_LIST_FILES' " To Get the Name of Files in Internal Table of Given Directory
    EXPORTING
      directory  = pdirp
      filter     = '*.*'
    IMPORTING
      file_count = file_count " Number of File in Directory
      dir_count  = dir_count " Number of Directory in Directory
    TABLES
      file_table = it_file " Table for Name of Files
      dir_table  = it_dir " Table for Name of Directories
    EXCEPTIONS
      cntl_error = 1
      OTHERS     = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  IF file_count IS NOT INITIAL.
    CALL FUNCTION 'GUI_DOWNLOAD'
      EXPORTING
        filename                = psavep " Path and Name of Excel File with Extension .xls
      TABLES
        data_tab                = it_file " Internal Table having all Name of Files
      EXCEPTIONS
        file_write_error        = 1
        no_batch                = 2
        gui_refuse_filetransfer = 3
        invalid_type            = 4
        no_authority            = 5
        unknown_error           = 6
        header_not_allowed      = 7
        separator_not_allowed   = 8
        filesize_not_allowed    = 9
        header_too_long         = 10
        dp_error_create         = 11
        dp_error_send           = 12
        dp_error_write          = 13
        unknown_dp_error        = 14
        access_denied           = 15
        dp_out_of_memory        = 16
        disk_full               = 17
        dp_timeout              = 18
        file_not_found          = 19
        dataprovider_exception  = 20
        control_flush_error     = 21
        OTHERS                  = 22.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
  ELSE.
    MESSAGE: 'No file found in the selected Directory' TYPE 'I'.
  ENDIF.

************************************************************************
*                          INITIALIZATION                              *
************************************************************************
INITIALIZATION.
  ftitle = 'Select from the following Options'.
  lpdirp = 'Directory of Fiels'.
  lpsavep = 'Path and Name of Excel File'.
  pdirp = 'C:\'.
  psavep = 'C:\test.xls'.

************************************************************************
*                   AT SELECTION-SCREEN ON VALUE-REQUEST               *
************************************************************************
*F4 for Getting Directory Path
AT SELECTION-SCREEN ON VALUE-REQUEST FOR pdirp.
  DATA: fname TYPE string.

  CALL METHOD cl_gui_frontend_services=>directory_browse
    EXPORTING
      window_title         = 'Select Directory'
    CHANGING
      selected_folder      = fname
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      not_supported_by_gui = 3
      OTHERS               = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  pdirp = fname.

*F4 for Getting File Path and Name
AT SELECTION-SCREEN ON VALUE-REQUEST FOR psavep.

  DATA: filename TYPE string,
        path TYPE string.

  CALL METHOD cl_gui_frontend_services=>file_save_dialog
    EXPORTING
      window_title         = 'Select path and file name'
      default_extension    = 'XLS'
    CHANGING
      filename             = filename
      path                 = path
      fullpath             = psavep
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      not_supported_by_gui = 3
      OTHERS               = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

Introduction

SAP has provided us with a lot of standard programs to make our day to day life easier. The standard code suite extends from simple programs to upload or download hierarchies to more complex ones to activate inactive objects in production. The flat file manipulation programs include programs to upload or download flat file to or from the system. But this list does not include one to transpose a flat file.

There are ‘n’ numbers of ways to achieve this. What is given in this article is to consider the separator values e.g. comma (,) or colon (;) as regular expressions and derive the values nested within the separators.

Regular Expressions

In computing, a regular expression provides a concise and flexible means for "matching" (specifying and recognizing) strings of text, such as particular characters, words, or patterns of characters - Wikipedia

For a general overview about regular expressions:  Regular Expression

Generally, in a given string any value that occurs repeatedly, be it in regular or random intervals, can be termed as a regular expression. In our case, any flat-file whose values are separated by an expression e.g. comma (,) or colon (;) can be taken to contain regular expressions with the separator as the expression itself.

REGEX

The REGEX command was introduced into ABAP with NetWeaver Release 2004s. It has been widely used for manipulating character strings and to search for specific expressions in text files which are extensive.

 A code sample for finding regular expression would be like,

FIND ALL OCCURRENCES OF REGEX <expression> IN <string> RESULTS <t_results>.

The above code would execute the REGEX command over the given string and store all occurrences of the ‘expression’ in an internal table

Note: A regular ‘csv’ file would not have a comma separator at the end of a record. An entry would be manually inserted in the program to identify the last value.

CODE

*&---------------------------------------------------------------------*
*& Report  ZFILE_TRANSPOSE
*&
*&---------------------------------------------------------------------*
REPORT  zfile_transpose.
*DECLARATION
TYPES: BEGIN OF st_file,
        rec TYPE string,
       END OF st_file.
TYPES: BEGIN OF st_inter,
        row_no TYPE i,
        rec TYPE string,
       END OF st_inter.
DATA : t_file TYPE TABLE OF st_file,                                  "Internal table to read file
       wa_file TYPE st_file,
       t_outfile TYPE TABLE OF st_file,
       wa_outfile TYPE st_file,
       t_inter TYPE TABLE OF st_inter,                                "Intermidiate table to store file
       wa_inter TYPE st_inter.
FIELD-SYMBOLS : <fs_file> TYPE st_file.
FIELD-SYMBOLS : <fs_inter> TYPE st_inter.
DATA : it_csv TYPE match_result_tab,                                  "Internal table for REGEX result
       wa_it_csv LIKE LINE OF it_csv.
DATA : col_count TYPE i,
       row_count TYPE i,
       loop_count1 TYPE i,
       loop_count2 TYPE i,
       col_len TYPE i,
       temp1 TYPE i,
       temp2 TYPE i,
       temp3 TYPE i,
       value TYPE string,
       char_len TYPE string.
CONSTANTS: c_filetype TYPE char10 VALUE 'ASC'.                       "For Filetype DAT

PARAMETERS: p_file1 LIKE rlgrap-filename OBLIGATORY.                 "Get file loacftion
PARAMETERS: p_file2 LIKE rlgrap-filename OBLIGATORY.                 "File loaction for transposed data
PARAMETERS: p_sptr TYPE c OBLIGATORY.                                "Character used for separator

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file1.                    "Get FILE from selection screen
*GET FILE PATH
  PERFORM get_file_path USING p_file1.

*&---------------------------------------------------------------------*
START-OF-SELECTION.
*UPLOAD DATA
  PERFORM get_data USING p_file1 CHANGING t_file.                    "Copy FILE data to internal table
*&---------------------------------------------------------------------*

*CREATE INTERNAL TABLE TO STORE DTO DETAILS
  READ TABLE t_file INTO wa_file INDEX 1.
  IF sy-subrc = 0.
    FIND ALL OCCURRENCES OF p_sptr IN wa_file-rec MATCH COUNT col_count.
    col_count = col_count + 1.                                       "To count number of columns
  ENDIF.
  LOOP AT t_file INTO wa_file.
    row_count = row_count + 1.                                       "To count number of rows
  ENDLOOP.
  LOOP AT t_file INTO wa_file.
    loop_count1  = sy-tabix.
    col_len = strlen( wa_file-rec ).                                 "Find length of each row
    FIND ALL OCCURRENCES OF REGEX p_sptr IN wa_file-rec RESULTS it_csv.
    IF sy-subrc = 0.
      wa_it_csv-offset = col_len.                                    "Create entry in regex table
      APPEND wa_it_csv TO it_csv.                                    "for last comma
    ELSE.
      MESSAGE 'Incorrect Separator Value' TYPE 'E'.
    ENDIF.
    temp1 = 0.
    LOOP AT it_csv INTO wa_it_csv.
      temp2 = temp3 = wa_it_csv-offset.
      temp2 = temp2 - temp1.
      value = wa_file-rec+temp1(temp2).                              "Get value between commas
      temp1 = temp3 + 1.
      loop_count2  = sy-tabix.
      IF loop_count1 = 1.
        wa_inter-row_no = loop_count2.                               "Include row number for each record
        CONCATENATE value p_sptr INTO wa_inter-rec.
        APPEND wa_inter TO t_inter.
      ENDIF.
      IF loop_count1 > 1 AND loop_count1 < row_count.                "Adding comma separation to transposed value
        READ TABLE t_inter ASSIGNING <fs_inter> WITH KEY row_no = loop_count2.
        IF sy-subrc = 0.
          CONCATENATE <fs_inter>-rec value p_sptr INTO <fs_inter>-rec.
          UNASSIGN <fs_inter>.
        ENDIF.
      ELSEIF loop_count1 EQ row_count.                               "No comma needed for last value
        READ TABLE t_inter ASSIGNING <fs_inter> WITH KEY row_no = loop_count2.
        IF sy-subrc = 0.
          CONCATENATE <fs_inter>-rec value INTO <fs_inter>-rec.
          UNASSIGN <fs_inter>.
        ENDIF.
      ENDIF.
    ENDLOOP.
  ENDLOOP.
  LOOP AT t_inter INTO wa_inter.
    wa_outfile-rec = wa_inter-rec.
    APPEND wa_outfile TO t_outfile.
  ENDLOOP.

*DOWNLOAD DATA
  PERFORM put_data USING p_file2 CHANGING t_outfile.                    "Copy FILE data to internal table
  IF sy-subrc = 0.
    MESSAGE 'File transposed Succesfully' TYPE 'S'.
  ENDIF.
*&---------------------------------------------------------------------*
*&      Form  GET_FILE_PATH
*&---------------------------------------------------------------------*
FORM get_file_path  USING    p_p_file1.
  DATA : wsl_upfile LIKE rlgrap-filename VALUE IS INITIAL.
  wsl_upfile = p_file1.
  CLEAR: p_file1.
  CALL FUNCTION 'KD_GET_FILENAME_ON_F4'
    EXPORTING
      PROGRAM_NAME        = SYST-REPID
      DYNPRO_NUMBER       = SYST-DYNNR
    CHANGING
      file_name           = wsl_upfile
    EXCEPTIONS
      MASK_TOO_LONG       = 1
      OTHERS              = 2.
  p_file1 = wsl_upfile.
ENDFORM.                    " GET_FILE_PATH
*&---------------------------------------------------------------------*
*&      Form  GET_DATA
*&---------------------------------------------------------------------*
FORM get_data  USING    p_p_file1
               CHANGING p_t_file TYPE table.
  DATA: l_file TYPE string.
  l_file =  p_p_file1.
  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      filename                = l_file
      filetype                = c_filetype
    TABLES
      data_tab                = p_t_file
    EXCEPTIONS
      file_open_error         = 1
      file_read_error         = 2
      no_batch                = 3
      gui_refuse_filetransfer = 4
      invalid_type            = 5
      no_authority            = 6
      unknown_error           = 7
      bad_data_format         = 8
      header_not_allowed      = 9
      separator_not_allowed   = 10
      header_too_long         = 11
      unknown_dp_error        = 12
      access_denied           = 13
      dp_out_of_memory        = 14
      disk_full               = 15
      dp_timeout              = 16
      OTHERS                  = 17.
  IF sy-subrc IS INITIAL.
  ELSE.
    MESSAGE s001(00) WITH 'File not found'.
    STOP.
  ENDIF.
  CLEAR l_file.
ENDFORM.                    " GET_DATA
*&---------------------------------------------------------------------*
*&      Form  PUT_DATA
*&---------------------------------------------------------------------*
FORM put_data  USING    p_p_file2
               CHANGING p_t_outfile TYPE table.
  DATA: l_outfile TYPE string.
  l_outfile = p_p_file2.
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                        = l_outfile
      filetype                        = c_filetype
    TABLES
      data_tab                        = p_t_outfile
    EXCEPTIONS
      file_write_error                = 1
      no_batch                        = 2
      gui_refuse_filetransfer         = 3
      invalid_type                    = 4
      no_authority                    = 5
      unknown_error                   = 6
      header_not_allowed              = 7
      separator_not_allowed           = 8
      filesize_not_allowed            = 9
      header_too_long                 = 10
      dp_error_create                 = 11
      dp_error_send                   = 12
      dp_error_write                  = 13
      unknown_dp_error                = 14
      access_denied                   = 15
      dp_out_of_memory                = 16
      disk_full                       = 17
      dp_timeout                      = 18
      file_not_found                  = 19
      dataprovider_exception          = 20
      control_flush_error             = 21
      OTHERS                          = 22.
  IF sy-subrc <> 0.
* Implement suitable error handling here
  ENDIF.
ENDFORM.                    " PUT_DATA

Author: Sujeet Mishra
Submitted: 22/8/2013
Description

CALL METHOD cl_gui_frontend_services=>execute
   EXPORTING
      document               = 'C:\Documents and Settings\xyz\Desktop\hi.txt'
 *    application            =
 *    parameter              =
 *    default_directory      =
 *    maximized              =
 *    minimized              =
 *    synchronous            =
 *    operation              = 'OPEN'
   EXCEPTIONS
     cntl_error             = 1
     error_no_gui           = 2
     bad_parameter          = 3
     file_not_found         = 4
     path_not_found         = 5
     file_extension_unknown = 6
     error_execute_failed   = 7
     synchronous_failed     = 8
     not_supported_by_gui   = 9
     others                 = 10
         .
 IF sy-subrc <> 0.
 * MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
 *            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
 ENDIF.

In SAP6.0, certain function modules have become obsolete. They need to be replaced by new function modules. Here I describe how to handle two of the most important function modules used to download/upload files from server - UPLOAD/ DOWNLOAD. These function modules have been replaced by GUI_UPLOAD/GUI_DOWNLOAD in 6.0. So when upgrading , we need to pay special attention while replacing the old function modules with the new ones as the data dypes and certain other parameters have changed. For example, in DOWNLOAD/UPLOAD function modules, a pop up screen used to appear which asked for the location of the file to be uploaded or downloaded. But the functionality is missing in the replacement fms. So in order to restore the previous functionality, we need to call a class method cl_gui_frontend_services=>file_open_dialog (for upload functionality) and cl_gui_frontend_services=>file_save_dialog (for download functionality) which gives the pop up.

Following code snippet shows how the replacement can be implemented. 

DOWNLOAD ::

CALL FUNCTION 'DOWNLOAD'
  EXPORTING
    filename   = p_out1  "' '
    filetype   = 'ASC'
    item       = 'Hierarchy'(t17)
    silent     = 'M'
    col_select = 'X'
  TABLES
    data_tab   = t_output.

 

Replaced with ::

DATA: l_p_out1_new TYPE string,
      l_filename TYPE string,
      l_fullpath TYPE string,
      l_path TYPE string.

MOVE p_out1 TO l_p_out1_new .

CALL METHOD cl_gui_frontend_services=>file_save_dialog
  EXPORTING
    default_file_name = l_p_out1_new
  CHANGING
    filename          = l_filename
    path              = l_path
    fullpath          = l_fullpath.
IF sy-subrc <> 0.

ENDIF.

CALL FUNCTION 'GUI_DOWNLOAD'
  EXPORTING
    filename                = l_fullpath
    filetype                = 'ASC'
    append                  = 'X'
  TABLES
    data_tab                = t_output
  EXCEPTIONS
    file_write_error        = 1
    no_batch                = 2
    gui_refuse_filetransfer = 3
    invalid_type            = 4
    no_authority            = 5
    unknown_error           = 6
    header_not_allowed      = 7
    separator_not_allowed   = 8
    filesize_not_allowed    = 9
    header_too_long         = 10
    dp_error_create         = 11
    dp_error_send           = 12
    dp_error_write          = 13
    unknown_dp_error        = 14
    access_denied           = 15
    dp_out_of_memory        = 16
    disk_full               = 17
    dp_timeout              = 18
    file_not_found          = 19
    dataprovider_exception  = 20
    control_flush_error     = 21
    OTHERS                  = 22.
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
          WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
 

UPLOAD ::

CALL FUNCTION 'UPLOAD'
  EXPORTING
    codepage                = ' '
    filename                = 'H:\data\BI-TEST.txt'
    filetype                = 'DAT'
  TABLES
    data_tab                = <p1>
  EXCEPTIONS
    conversion_error        = 1
    invalid_table_width     = 2
    invalid_type            = 3
    no_batch                = 4
    unknown_error           = 5
    gui_refuse_filetransfer = 6
    OTHERS                  = 7.
 

Replaced with ::

DATA:lt_file_table TYPE filetable.
DATA:lw_file  TYPE file_table.
DATA:l_rc TYPE i.
DATA:BEGIN OF lt_itab OCCURS 0 ,
     l_c1 TYPE string,
     END OF lt_itab.

DATA:l_action TYPE i.
DATA l_filename_new TYPE string .

CALL METHOD cl_gui_frontend_services=>file_open_dialog
  EXPORTING
    default_filename = 'H:TEST.TXT'
  CHANGING
    file_table       = lt_file_table
    rc               = l_rc
    user_action      = l_action.

IF l_action NE 9.

  READ TABLE  lt_file_table INTO lw_file INDEX 1.
  l_filename_new = lw_file-filename.

*Upload FM Replaced with Gui_upload
  CALL FUNCTION 'GUI_UPLOAD'
    EXPORTING
      codepage            = ''
      filename            = l_filename_new
      filetype            = 'ASC'
      has_field_separator = 'X'
    TABLES
      data_tab            = <p1>
    EXCEPTIONS
      no_batch            = 4
      invalid_type        = 3
      unknown_error       = 5
      OTHERS              = 7.
  .

  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*          WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDIF.
 

Description : There are instances, when some garbage characters creep into the data while reading from a text file ( .txt ) in application server. It may get the upload totoaly wrong and can give incoorect results during execution. Heres a simple snippet to uplaod data from application server into SAP internal Table without any garbage characters in the data. The only thing to be kept in mind is that it works on for text files (.txt)

FIELD-SYMBOLS: <fs> TYPE x_upload.
FIELD-SYMBOLS: <fs_struc> TYPE any.
FIELD-SYMBOLS: <fs_itab> TYPE table.

DATA :l_sys_cp  LIKE tcp00-cpcodepage.
DATA : l_tcp00   LIKE tcp00.
DATA : l_lan_cp  LIKE tcp00-cpcodepage.

*   check code page first
CALL FUNCTION 'SYSTEM_CODEPAGE'
  IMPORTING
    codepage = l_sys_cp.

SELECT SINGLE * FROM tcp00 INTO l_tcp00 WHERE cpcodepage = l_sys_cp.

CONSTANTS :c_rc4       LIKE sy-subrc   VALUE 4.

CALL FUNCTION 'SCP_CODEPAGE_FOR_LANGUAGE'
  EXPORTING
    language = sy-langu
  IMPORTING
    codepage = l_lan_cp
  EXCEPTIONS
    OTHERS   = c_rc4.
IF sy-subrc <> 0.
  l_lan_cp = l_sys_cp.
ENDIF.

DATA : i_tab_input_data TYPE truxs_t_text_data.

ASSIGN i_tab_input_data[] TO <fs_itab>.
ASSIGN LOCAL COPY OF INITIAL LINE OF <fs_itab> TO <fs_struc>.

OPEN DATASET p_upload FOR INPUT IN TEXT MODE
                      ENCODING DEFAULT.   "also check the option of ... CODE PAGE cp in help

WHILE sy-subrc = 0.
  READ DATASET p_upload INTO <fs_struc>.
  APPEND <fs_struc> TO <fs_itab>.
ENDWHILE.

CLOSE DATASET p_upload.

DATA: ld_lan_cp TYPE abap_encod.

ld_lan_cp = l_lan_cp.
CALL FUNCTION 'TRANSLATE_CODEPAGE_IN'
  EXPORTING
    codepage_from = ld_lan_cp
  TABLES
    t_data        = <fs_itab>
  EXCEPTIONS
    OTHERS        = 0.

DATA: l_file_name_string TYPE string,
      l_file_format_10 TYPE char10.

l_file_name_string = p_upload.
l_file_format_10 = 'ASC'.

CONSTANTS : c_rc0       LIKE sy-subrc   VALUE 0,
            c_rc8       LIKE sy-subrc   VALUE 8,
            c_rc12      LIKE sy-subrc  VALUE 12,
            c_rc16      LIKE sy-subrc  VALUE 16.

DATA : l_totalsize   TYPE i.

DATA : l_fm_name LIKE tfdir-funcname.
DATA : l_tfdir   LIKE tfdir.
DATA : i_line_header TYPE char01.

l_fm_name = 'TEXT_CONVERT_TXT_TO_SAP'.

SELECT SINGLE * FROM tfdir INTO l_tfdir
  WHERE funcname = l_fm_name.

IF sy-subrc = 0.
  CALL FUNCTION l_fm_name
    EXPORTING
      i_fileformat         = 'TXT'
      i_field_seperator    = 'X'
      i_line_header        = i_line_header
      i_tab_raw_data       = <fs_itab>
      i_filename           = p_upload
      i_totalsize          = l_totalsize
    TABLES
      i_tab_converted_data = it_upload
    EXCEPTIONS
      OTHERS               = c_rc4.
ELSE.
  MESSAGE e046(fl) WITH l_fm_name RAISING conversion_failed.
ENDIF.
IF sy-subrc <> c_rc0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
          WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4
                                     RAISING conversion_failed.
ENDIF.

Author: Eswar Kanakanti

Submitted: 20-Apr-2007

Summary:
 
This is an ABAP program, downloads a file based on the user provided delimit characters on the selection screen dynamically.

In case of Tab delimit character, user has to provide 'T' so that program will create a tab delimit file.
Source Code:

REPORT  zfile_with_delchar.
TABLES:
  mara.
*******Types Declaration
TYPES:
**--File Output
  BEGIN OF ty_out,
    line(150),
  END OF ty_out,
**--Material Data
  BEGIN OF ty_mat,
    matnr TYPE mara-matnr,
    mtart TYPE mara-mtart,
    mbrsh TYPE mara-mbrsh,
    meins TYPE mara-meins,
  END OF ty_mat.
DATA:
  it_out TYPE STANDARD TABLE OF ty_out WITH HEADER LINE,
  it_mat TYPE STANDARD TABLE OF ty_mat WITH HEADER LINE.
**--Selection-screen Design
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-001.
**--Material numbers
SELECT-OPTIONS s_matnr FOR mara-matnr.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(15) text-002.
**--Delimit char
PARAMETERS: p_dchar TYPE c OBLIGATORY.
SELECTION-SCREEN COMMENT 20(20) text-003.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK b1.
CLASS cl_abap_char_utilities DEFINITION LOAD.

START-OF-SELECTION.
**--Get the data from material table
  SELECT matnr
         mtart
         mbrsh
         meins
    FROM mara
    INTO TABLE it_mat
   WHERE matnr IN s_matnr.
**--Prepare output file with specified delimit char
  LOOP AT it_mat.
    IF p_dchar = 'T'.
      CONCATENATE it_mat-matnr
                  it_mat-mtart
                  it_mat-mbrsh
                  it_mat-meins
             INTO it_out-line
             SEPARATED BY cl_abap_char_utilities=>horizontal_tab.
    ELSE.
      CONCATENATE it_mat-matnr
                  it_mat-mtart
                  it_mat-mbrsh
                  it_mat-meins
             INTO it_out-line
             SEPARATED BY p_dchar.
    ENDIF.
    APPEND it_out.
    CLEAR: it_out,it_mat.
  ENDLOOP.
**--Download the data
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                = 'C:\mat.txt'
    TABLES
      data_tab                = it_out
    EXCEPTIONS
      file_write_error        = 1
      no_batch                = 2
      gui_refuse_filetransfer = 3
      invalid_type            = 4
      no_authority            = 5
      unknown_error           = 6
      header_not_allowed      = 7
      separator_not_allowed   = 8
      filesize_not_allowed    = 9
      header_too_long         = 10
      dp_error_create         = 11
      dp_error_send           = 12
      dp_error_write          = 13
      unknown_dp_error        = 14
      access_denied           = 15
      dp_out_of_memory        = 16
      disk_full               = 17
      dp_timeout              = 18
      file_not_found          = 19
      dataprovider_exception  = 20
      control_flush_error     = 21
      OTHERS                  = 22.
  IF sy-subrc = 0.
    WRITE:/ 'File is downloaded'.
  ENDIF.

Selection-screen:

Author: Vijay Babu Dudla

Submitted: 11.08.2008

Description: This report is used to Convert the Internal table to HTML formated table.  

 'WWW_ITAB_TO_HTML_HEADERS'  "This is used to Set the Column properties

  'WWW_ITAB_TO_HTML_LAYOUT'  "This is used to set the layout properties

 'WWW_ITAB_TO_HTML'   "Using the Columns Definitions and Internal table this Function converts the internal table data into HTML format.

REPORT zdownload_table_html.
*-Internal table Declaration
TYPES: BEGIN OF ty_vbap,
         vbeln TYPE vbeln,
         posnr TYPE posnr,
         matnr TYPE matnr,
       END OF ty_vbap.
*-ALL related Declarations
DATA: t_header TYPE STANDARD TABLE OF w3head WITH HEADER LINE,  "Header
         t_fields TYPE STANDARD TABLE OF w3fields WITH HEADER LINE,    "Fields
         t_html TYPE STANDARD TABLE OF w3html,
         wa_header TYPE w3head,
         w_head TYPE w3head.
DATA: it_vbap TYPE STANDARD TABLE OF ty_vbap,
         it_fcat TYPE lvc_t_fcat WITH HEADER LINE.
START-OF-SELECTION.
  SELECT vbeln posnr matnr
          FROM vbap
          INTO TABLE it_vbap
         UP TO 20 ROWS.
END-OF-SELECTION.
*-Populate the Columns
  it_fcat-coltext = 'SalesOrder'.
  APPEND it_fcat.
  it_fcat-coltext = 'ItmeNumber'.
  APPEND it_fcat.
  it_fcat-coltext = 'Material'.
  APPEND it_fcat.
*-Fill the Column heading and Filed Properties
  LOOP AT it_fcat.
    w_head-text = it_fcat-coltext.
    CALL FUNCTION 'WWW_ITAB_TO_HTML_HEADERS'
      EXPORTING
        field_nr = sy-tabix
        text     = w_head-text
        fgcolor  = 'black'
        bgcolor  = 'green'
      TABLES
        header   = t_header.
    CALL FUNCTION 'WWW_ITAB_TO_HTML_LAYOUT'
      EXPORTING
        field_nr = sy-tabix
        fgcolor  = 'black'
        size     = '3'
      TABLES
        fields   = t_fields.
  ENDLOOP.
*-Title of the Display
  wa_header-text = 'Sales Order Details' .
  wa_header-font = 'Arial'.
  wa_header-size = '2'.
*-Preparing the HTML from Intenal Table
  REFRESH t_html.
  CALL FUNCTION 'WWW_ITAB_TO_HTML'
    EXPORTING
      table_header = wa_header
    TABLES
      html         = t_html
      fields       = t_fields
      row_header   = t_header
      itable       = it_vbap.
*-Download  the HTML into frontend
  CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                = 'C:\Sales.htm'
    TABLES
      data_tab                = t_html
    EXCEPTIONS
      file_write_error        = 1
      no_batch                = 2
      gui_refuse_filetransfer = 3
      invalid_type            = 4
      no_authority            = 5
      unknown_error           = 6
      header_not_allowed      = 7
      separator_not_allowed   = 8
      filesize_not_allowed    = 9
      header_too_long         = 10
      dp_error_create         = 11
      dp_error_send           = 12
      dp_error_write          = 13
      unknown_dp_error        = 14
      access_denied           = 15
      dp_out_of_memory        = 16
      disk_full               = 17
      dp_timeout              = 18
      file_not_found          = 19
      dataprovider_exception  = 20
      control_flush_error     = 21
      OTHERS                  = 22.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
*-Display the HTML file
  CALL METHOD cl_gui_frontend_services=>execute
    EXPORTING
      document               = 'C:\Sales.htm'
      operation              = 'OPEN'
    EXCEPTIONS
      cntl_error             = 1
      error_no_gui           = 2
      bad_parameter          = 3
      file_not_found         = 4
      path_not_found         = 5
      file_extension_unknown = 6
      error_execute_failed   = 7
      synchronous_failed     = 8
      not_supported_by_gui   = 9
      OTHERS                 = 10.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

Initial Author: Xinpeng Lin

Submitted: 11.9.2007

Other Authors: see Page History

This Code Snippets will clarify some general process of working with files when ABAP programming. Such as,Uploading/Downloading files from/to Application/Presentation server, adding F4 help to file path on the selection-screen,checking file existence.

Check File Existence

Before we process the file which is input on the selection screen by end-user, we need to check whether this file exists or not. If it does not exist, we just give an error message and need not to go into the main program .This logic should be done within the event 'AT SELECTION-SCREEN'.

presentation server file

For the presentation server file,here intruduce 2 ways, one is Function Module, the other is Class Static Method.

1. Using Funciton Moudle 'DX_FILE_EXISTENCE_CHECK'.
 

DATA: gdf_file_exist(1) TYPE c.
PARAMETERS p_file   TYPE dxfile-filename.

AT SELECTION-SCREEN.
CALL FUNCTION 'DX_FILE_EXISTENCE_CHECK'
    EXPORTING
      filename          = p_file
      pc                = 'X'
*   SERVER              =
    IMPORTING
      file_exists       = gdf_file_exist.

IF NOT ( sy-subrc = 0 and gdf_file_exist = 'X' )
  MESSAGE  'the input file does not exist.' TYPE 'E'.
ENDIF.

Pay attention to the importing parameter 'pc', it should be set as 'X'.

2. Using Class Static Method 'CL_GUI_FRONTEND_SERVICES=>FILE_EXIST'

DATA: gdf_file_exist(1) TYPE c.
PARAMETERS p_file   TYPE dxfile-filename.

AT SELECTION-SCREEN.
CALL METHOD cl_gui_frontend_services=>file_exist
    EXPORTING
      file             = p_file
    RECEIVING
      result           = gdf_file_exist.

IF NOT ( sy-subrc = 0 and gdf_file_exist = 'X' )
  MESSAGE  'the input file does not exist.' TYPE 'E'.
ENDIF.

application server file

Open it first within the event 'AT SELECTION-SCREEN'.If it can be opened successfully, this file exists.  After open, do not forget to close it.

PARAMETERS p_file   TYPE dxfile-filename.
AT SELECTION-SCREEN.
OPEN DATASET p_file FOR INPUT IN TEXT MODE ENCODING DEFAULT.

IF sy-subrc = 0.
  CLOSE DATASET p_file.
ELSE.
  MESSAGE  'the input file does not exist.' TYPE 'E'.
ENDIF.

Function Module 'OCS_GET_FILE_INFO'
 

DATA: gdt_ocs_file TYPE TABLE OF ocs_file.
PARAMETERS p_file   TYPE dxfile-filename.

AT SELECTION-SCREEN.
CALL FUNCTION 'OCS_GET_FILE_INFO'
    EXPORTING
      dir_name           = p_file
      file_name          =  '*'
    TABLES
      dir_list               = gdt_ocs_file.

Importing parameter 'file_name' is set as '*' means all the file in the specfied directory will be get and stored in the internal table 'gdt_ocs_file'. If the input file is included in the internal table, this file exists.

Add F4 Help

Adding one F4 Help to the file path on the selection-screen will be very helpful to the end-user.The logic should be under the event 'ON VALUE-REQUEST'.

presentation server file

For the presentation server file,here intruduce 2 ways, one is Function Module, the other is Class Static Method.

1. Using Function Module 'F4_FILENAME'.

PARAMETERS p_file      TYPE dxfile-filename.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

CALL FUNCTION 'F4_FILENAME'
*   EXPORTING
*     PROGRAM_NAME        =
*     DYNPRO_NUMBER      =
*     FIELD_NAME                =
   IMPORTING
     file_name           = p_file.

2. Using Method 'CL_GUI_FRONTEND_SERVICES=>FILE_OPEN_DIALOG'.

DATA: gdt_filetable TYPE filetable.
DATA: gdf_rc          TYPE I.
PARAMETERS p_file      TYPE dxfile-filename.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

CALL METHOD cl_gui_frontend_services=>file_open_dialog
   EXPORTING
      WINDOW_TITLE     = 'Choose a file'
   CHANGING
      file_table       = gdt_filetable
      rc               = gdf_rc.
IF sy-subrc = 0.
    READ TABLE gdt_filetable
     INTO gds_filetable  INDEX 1.
    p_file = gds_filetable-filename.
ENDIF.

gdf_rc is the number of selected file, if it is equal -1, error occured.

application server file

Generally it need not to provide F4 help for application server file. If we want it, there is also a Function Module which can be used.
 

PARAMETERS p_file TYPE dxfile-filename.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.

CALL FUNCTION 'F4_DXFILENAME_4_DYNP'
 EXPORTING
      dynpfield_filename = 'P_FILE'
      dyname                    = sy-repid
      dynumb                    = sy-dynnr
      filetype                     = 'P'
      location                    = 'A'
      server                       = '  '.

 filetype: 'P' represents Physical file name; 'L' represents Logical file name.
 location: 'A' represents Application Server; 'P' represents Presentation server.
 

Download Files

Sometimes we need to save the internal table data as a file for the further process.For download to presentation server and download to application server,they are 2 different kinds of  process methods.

to presentation server

When storing internal table data as a local file on the presentation server, there are 2 methods we can use.
One is using the function modeule, the other is using the class static method.

1. Using Function Module 'GUI_DOWNLOAD'.

DATA: gdf_filepath type dxfile-filename
DATA: gdt_data type table of gts_data.

START-OF-SELECTION.

gdf_filepath = 'C:\mydata.txt'.

CALL FUNCTION 'GUI_DOWNLOAD'
    EXPORTING
      filename                        = gdf_filepath
      filetype                          = 'ASC'
      write_field_separator   = 'X'
    TABLES
      data_tab                        =  gdt_data.

filetype is set by 'X' mens separating columns by Tabs in case of ASCII download.
If sy-subrc is equal 0, file downloading is successful.

2. Using class static method 'CL_GUI_FRONTEND_SERVICES =>GUI_DOWNLOAD'
 

DATA: gdf_filepath type dxfile-filename
DATA: gdt_data type table of gts_data.

START-OF-SELECTION.

gdf_filepath = 'C:\mydata.txt'.

CALL METHOD cl_gui_frontend_services=>gui_download
    EXPORTING
      filename                      = gdf_filepath
      filetype                        = 'ASC'
      write_field_separator  = 'X'
CHANGING
      data_tab                      = gdt_data.

filetype is set by 'X' mens separating columns by Tabs in case of ASCII download.
If sy-subrc is equal 0, file downloading is successful.

to application server

If we want to save the internal table data to the application server, there is no function module or class static method which we can use, we must write the code by ourselves.

1. no separator between field columns

DATA: gdf_filepath type dxfile-filename
DATA: gdt_data type table of gts_data.
DATA: ldf_length type i.
FIELD-SYMBOLS: <lfs_outfile> TYPE gts_data

START-OF-SELECTION.

  gdf_filepath = 'C:\mydata.txt'.

  OPEN  DATASET gdf_filepath FOR OUTPUT  IN TEXT MODE  ENCODING DEFAULT.

  LOOP AT prt_data ASSIGNING <lfs_outfile>.
    TRANSFER <lfs_outfile> TO prf_file.
  ENDLOOP.

  CLOSE DATASET gdf_filepath.

The prerequisite is the field of prt_data must be character type.
Using this method, every field column will output as the length defined,without separator.

2. tab separator between field columns

DATA: gdf_filepath type dxfile-filename
DATA: gdt_data type table of gts_data.
DATA: ldf_length type i.
FIELD-SYMBOLS: <lfs_outfile> TYPE gts_data

START-OF-SELECTION.

gdf_filepath = 'C:\mydata.txt'.

OPEN  DATASET gdf_filepath FOR OUTPUT  IN TEXT MODE  ENCODING DEFAULT.

LOOP AT prt_data ASSIGNING <lfs_outfile>.
        CONCATENATE    <LFS_OUTFILE>-BUKRS
                                        <LFS_OUTFILE>-BUDAT
                                        ...
                           INTO    LDF_OUTDATA
        SEPARATED BY
                           CL_ABAP_CHAR_UTILITIES=>HORIZONTAL_TAB.

        TRANSFER LDF_OUTDATA   TO gdf_filepath.
ENDLOOP.

CLOSE  DATASET gdf_filepath.

Upload Files

Sometimes we need to upload the file data to the internal table first, and then process it.For upload from presentation server and upload from application server,they are 2 different kinds of process methods.

from presentation server

When we upload a file data from presentation server to the internal table, there are 2 method that we can choose.One is using the Function Moduel, the other is using the class static method.

1. Using function module 'GUI_UPLOAD'
 

DATA: gdt_filedata TYPE TABLE OF gts_filedata.
PARAMETERS p_file TYPE dxfile-filename.

START-OF-SELECTION.
CALL FUNCTION 'GUI_UPLOAD'
      EXPORTING
        filename                = p_file
        has_field_separator     = 'X'
      TABLES
        data_tab                = gdt_filedata.

parameter has_field_separator is set as  'X'  means columns separated by tabs in case of ASCII upload.

2. Using the method 'CL_GUI_FRONTEND_SERVICES =>GUI_UPLOAD'
 

DATA: gdt_filedata TYPE TABLE OF gts_filedata.
PARAMETERS p_file TYPE dxfile-filename.

START-OF-SELECTION.

CALL METHOD cl_gui_frontend_services=>gui_upload
    EXPORTING
      filename              = p_file
      has_field_separator   = 'X'
    CHANGING
       data_tab             = prt_table.

 parameter 'has_field_separator' is set as  'X'  means columns separated by tabs in case of ASCII upload.

from application server

If we want to upload file data from the application server to the internal table, there is no function module or class static method which we can use, we must wirte the code by ourselves.

1. no separator between field columns
 

PARAMETERS p_file  TYPE dxfile-filename.

START-OF-SELECTION.

OPEN DATASET p_file IN TEXT MODE ENCODING DEFAULT FOR INPUT.

  DO.
    READ DATASET p_file INTO gds_data.
    IF sy-subrc <> 0.
      EXIT.
    ENDIF.

    APPEND gds_data TO gdt_data.
  ENDDO.

CLOSE DATASET p_file.

2. tab separator between field columns
 

DATA: gds_field_split type gts_data.
FIELD-SYMBOLS: <fs_field> TYPE gts_data.
PARAMETERS p_file  TYPE dxfile-filename.

START-OF-SELECTION.

OPEN DATASET prf_file IN TEXT MODE ENCODING DEFAULT FOR INPUT.

  DO.
    READ DATASET p_file INTO gds_field.
    SPLIT gds_field  AT cl_abap_char_utilities=>horizontal_tab
         INTO TABLE gdt_field_split.

   LOOP AT gdt_field_split  into gds_field_split.
       gdf_index = gdf_index + 1.
       ASSIGN COMPONENT gdf_index OF STRUCTURE
             gds_data to <fs_field>.

      IF sy-subrc = 0.
          <fs_field> = gds_field_split.
      ENDIF.
   ENDLOOP.

    APPEND gds_data TO gdt_data.
  ENDDO.


CLOSE DATASET p_file.